Eine LED-Matrix 5x7 ansteuern

Hi, als erstes möchte ich nochmal für die Hilfe bei meinem Problem mit Frequenzzähler bedanken.
Nun ist leider ein neues Problem aufgetaucht.
Ich möchte gerne eine LED Matrix 5x7 direkt mit einem Atmega16 ansteuern.
Als erstes habe ich versucht schritt für schritt jeden Port an und aus zu schalten, funktioniert auch, jedoch ist der Code sehr lang....

Code:

---

Do

'---------------------------------
'"1" Anzeigen
'---------------------------------
      Portb = &B11111101
      Portd = &B00000010
      Waitus Zeit
      Portb = &B11111110
      Portd = &B00000100
      Waitus Zeit
      Portb = &B11111101
      Portd = &B00000100
      Waitus Zeit
      Portb = &B11111011
      Portd = &B00000100
      Waitus Zeit
      Portb = &B11110111
      Portd = &B00000100
      Waitus Zeit
      Portb = &B11101111
      Portd = &B00000100
      Waitus Zeit
      Portb = &B11011111
      Portd = &B00000100
      Waitus Zeit
      Portb = &B10111111
      Portd = &B00000100
      Waitus Zeit
      Portb = &B10111111
      Portd = &B00000010
      Waitus Zeit
      Portb = &B10111111
      Portd = &B00001000
      Waitus Zeit
      Portb = &B11111111
      Portd = &B00000000

Loop

---

Kennt ihr vielleicht eine Möglichkeit das Programm effektiver zu schreiben?

Vielen Dank für eure Hilfe

mfg Tryan

Also mir fallen auf Anhieb 2-3 Möglichkeiten ein, das in C oder Assembler zu machen (vorzugsweise C), aber für BASCOM musst Du wohl auf die Bascom-Profis warten...

Hallo Tryan,
unabhängig von der Programmiersprache würde ich zunächst mal in Frage stellen, jeden Punkt einzeln anzusteuern. Dass würde erstens zu viele Befehle benötigen (wie du bei dir siehst) und zweitens bestimmt zu ziemlichem Flimmern führen.
Wenn dein Portd immer eine Spalte freigibt, dann kannst du die 7 Punkte in einem Befehl schalten. Dazu würde ich für jedes Zeichen die fünf Spalten nacheinander durchgehen und die 5 Werte z.B. aus dem EEProm holen, wo du sie vorher für jede Zahl abgespeichert hast.
In BASCOM würde das dann etwa so aussehen:

Code:

---

Dim Offset As Word
Dim Zeichen As String * 1
Dim Spalte As Byte
Dim Werte As Byte
Declare Sub Out_zeichen(byval Z As String)
Do
  Zeichen = "1"
  Call Out_zeichen(zeichen)
Loop

Sub Out_zeichen(byval Z As String)
  Offset = Asc(zeichen) - 49                              'sucht Werte für Zeichen "1" ab EEProm Adresse 1
  Offset = Offset * 5                                      'immer 5 Werte pro Zeichen
  Spalte = 1
  Portb = &B11111111
  Do
      Portd = 0                                            'zum Verhindern von Geisterbildern
      Incr Offset                                          'geht die 5 Werte durch
      Readeeprom Werte, Offset
      Portb = Werte                                        'lädt die Werte
      Portd = Spalte                                        'Gibt die Spalte frei
      Print Bin(werte)                                      'zum Testen
      Shift Spalte , Left                                  'erhöht auf die nächste Spalte
  Loop Until Spalte = 32                                  'stoppt nach der 5. Spalte
End Sub


$eeprom
Data &B00000000                                            'Zelle 0 im EEProm nicht benutzen!!!
Data &B11111111 , &B10111101 , &B10000000 , &B10111111 , &B11111111      '1
Data &B10111101 , &B10011110 , &B10101110 , &B10110110 , &B10111001      '2

---

Gruß

Rolf

Hi for_ro
danke für deine Hilfe.
Ich habe dein Programm getestet leider zeigt die Anzeige nix an.
Um ein Fehler aus meiner Seite auszuschießen könntest du mir dein Programm ein wenig näher erklären.

Ich verstehe es soweit das die Spalten mit PortD nach und nach geschaltet werden.
1Spalte=>2Splate=>3Spalte=>4Spalte=>5Spalte=>1Spal te usw...

Wenn die erste 1 Spalte "ausgewählt" ist, wird der erste Wert von dem EEPROM an PortB ausgeben

Wenn die erste 2 Spalte "ausgewählt" ist, wird der zweite Wert von dem EEPROM an PortB ausgeben
usw..

Stimmt das soweit?

Aber warum bauche ich nur 5 Werte um 7 Zeilen mit ProtB anzusteuern? Es müsten doch sieben sein oder?

Mfg Tryan

Hast du jetzt nur meinen Teil genommen, oder gehört von dir da auch noch was drumherum?
Ich habe z.B. keinen µC ausgewählt, die Ports nicht konfiguriert usw, sondern nur den Teil beschrieben, der deinem Programmstück entspricht.

Du kannst doch die "Pixel" der 5*7 Matrix nur ein und ausschalten, also 1 für aus und 0 für ein. Da sie alle hintereinander auf Port B liegen wird der Port komplett auf den Wert aus dem EEProm gesetzt.
Ich habe die Werte binär ins EEProm geschrieben, damit du die 7 bits gleich sehen kannst. Das 8. bit ist immer aus, also immer 1.
Du musst die Daten ins EEProm übrigens separat übertragen, zumindest muss ich das mit meinem Programmer. Das geht nach dem Kompilieren über den EEProm Tab des Programmers.

Gruß

Rolf

Hi, also ich hab dein teil genommen und hab einfach meinen µC ausgewählt und die Ports konfiguriert.

Code:

---

$regfile = "m16DEF.DAT"
$crystal = 16000000
Config Porta = Input
Config Portb = Output
Config Portc = Output
Config Portd = Output


Dim Offset As Word
Dim Zeichen As String * 1
Dim Spalte As Byte
Dim Werte As Byte
Declare Sub Out_zeichen(byval Z As String)


Do
  Zeichen = "1"
  Call Out_zeichen(zeichen)

Loop

Sub Out_zeichen(byval Z As String)
  Offset = Asc(zeichen) - 49                    'sucht Werte für Zeichen "1" ab EEProm Adresse 1
  Offset = Offset * 5                            'immer 5 Werte pro Zeichen
  Spalte = 1
  Portb = &B11111111
  Do
      Portd = 0                                  'zum Verhindern von Geisterbildern
      Incr Offset                                'geht die 5 Werte durch
      Readeeprom Werte , Offset
      Portb = Werte                              'lädt die Werte
      Portd = Spalte                              'Gibt die Spalte frei
      Print Bin(werte)                            'zum Testen
      Shift Spalte , Left                        'erhöht auf die nächste Spalte
  Loop Until Spalte = 32                        'stoppt nach der 5. Spalte
End Sub


$eeprom
Data &B00000000                                  'Zelle 0 im EEProm nicht benutzen!!!
Data &B11111111 , &B10111101 , &B10000000 , &B10111111 , &B11111111      '1
Data &B10111101 , &B10011110 , &B10101110 , &B10110110 , &B10111001      '2

---

Hab ich irgendwas vergessen?

Mfg Tryan

Hi,
ich hab noch mal editiert weil ich deine letzte Frage übersehen hatte.

Und in der Funktion musst du noch die globale Variable 'Zeichen' durch den Parameter Z ersetzen. Sorry.
Wenn es dir am Ende auf Geschwindigkeit ankommt, solltest du keine Sub mit Parameter aufrufen, dass braucht zu viel Zeit.

Gruß

Rolf

Hi for_ro

Ich habe das Zeichen durch das Z verändern, jedoch gab es keine Änderung. Anzeige bleibt leer

In der Simulation scheint das Programm auch richtig zu laufen, aber nur wenn ich F8 drücke...
Ich programmiere den ATmega16 mit Ponyprog2000 und da kann ich auch den EEPROM separat mit der BASCOM erstellten *.eep Datei beschreiben. Jedoch wenn ich den EEPROM vom ATmega16 auslese ist der immer leer. Muss man die "DATA" unbedingt ins EEPROM schreiben?

Code:

---



$regfile = "m16DEF.DAT"
$crystal = 16000000
Config Porta = Output
Config Portb = Output
Config Portc = Output                            'Zeilen
Config Portd = Output                            'Spalten


Dim Offset As Word
Dim Zeichen As String * 1
Dim Spalte As Byte
Dim Werte As Byte
Declare Sub Out_zeichen(byval Z As String)

Porta = &B11111111


Do
  Zeichen = "3"
  Call Out_zeichen(zeichen)


Loop

Sub Out_zeichen(byval Z As String)
  Offset = Asc(z) - 49                          'sucht Werte für Zeichen "1" ab EEProm Adresse 1
  Offset = Offset * 5                            'immer 5 Werte pro Zeichen
  Spalte = 1
  Portc = &B11111111
  Do
      Portd = 0                                  'zum Verhindern von Geisterbildern
      Incr Offset                                'geht die 5 Werte durch
      Readeeprom Werte , Offset
      Portc = Werte                              'lädt die Werte
      Portd = Spalte                              'Gibt die Spalte frei
      Print Bin(werte)                            'zum Testen

      Shift Spalte , Left                        'erhöht auf die nächste Spalte
  Loop Until Spalte = 32                        'stoppt nach der 5. Spalte

End Sub


$eeprom
Data &B00000000                                  'Zelle 0 im EEProm nicht benutzen!!!
Data &B11111111 , &B10111101 , &B10000000 , &B10111111 , &B11111111      '1
Data &B10111101 , &B10011110 , &B10101110 , &B10110110 , &B10111001      '2
Data &B11111111 , &B00000000 , &B11111111 , &B00000000 , &B11111111      '3 TEST

---

Brauchst du nur so abändern, dann sind die Zeichen im Flash.

Code:

---

$regfile = "m16DEF.DAT"
$crystal = 16000000
Config Porta = Output
Config Portb = Output
Config Portc = Output                            'Zeilen
Config Portd = Output                            'Spalten

Dim Offset As Word
Dim Zeichen As String * 1
Dim Spalte As Byte
Dim Werte As Byte
Declare Sub Out_zeichen(byval Z As String)

Porta = &B11111111

Do
  Zeichen = "3"
  Call Out_zeichen(zeichen)
Loop

End

Sub Out_zeichen(byval Z As String)
  Offset = Asc(z) - 49                          'sucht Werte für Zeichen "1" ab EEProm Adresse 1
  Offset = Offset * 5                            'immer 5 Werte pro Zeichen
  Spalte = 1
  Portc = &B11111111
  Do
      Portd = 0                                  'zum Verhindern von Geisterbildern
      Incr Offset                                'geht die 5 Werte durch
      Werte=Lookup(Offset,Zeichen_data)
      'Readeeprom Werte , Offset
      Portc = Werte                              'lädt die Werte
      Portd = Spalte                              'Gibt die Spalte frei
      Print Bin(werte)                            'zum Testen

      Shift Spalte , Left                        'erhöht auf die nächste Spalte
  Loop Until Spalte = 32                        'stoppt nach der 5. Spalte

End Sub


'$eeprom
Zeichen_data:
Data &B00000000                                  'Zelle 0 im EEProm nicht benutzen!!!
Data &B11111111 , &B10111101 , &B10000000 , &B10111111 , &B11111111      '1
Data &B10111101 , &B10011110 , &B10101110 , &B10110110 , &B10111001      '2
Data &B11111111 , &B00000000 , &B11111111 , &B00000000 , &B11111111      '3 TEST

---

Hi for_ro

Von der Grundfunktion, funktionier das Programm nun

Code:

---


$regfile = "m16DEF.DAT"
$crystal = 16000000
Config Porta = Output
Config Portb = Output
Config Portc = Output                            'Zeilen
Config Portd = Input                              'Spalten

Dim Offset As Word
Dim Zeichen As String * 1
Dim Spalte As Byte
Dim Werte As Byte
Declare Sub Out_zeichen(byval Z As String)



Do

  Zeichen = "1"
  Call Out_zeichen(zeichen)



Loop

End

Sub Out_zeichen(byval Z As String)
  Offset = Asc(z) - 49                          'sucht Werte für Zeichen "1"
  Offset = Offset * 5                            'immer 5 Werte pro Zeichen
  Spalte = 1
  Portc = &B11111111
  Do
      Porta = 0                                  'zum Verhindern von Geisterbildern
      Incr Offset                                'geht die 5 Werte durch
      Werte = Lookup(offset , Zeichen_data)

      Portc = Werte                              'lädt die Werte
      Porta = Spalte                              'Gibt die Spalte frei
      Waitms 5

      Shift Spalte , Left                        'erhöht auf die nächste Spalte
  Loop Until Spalte = 32                        'stoppt nach der 5. Spalte

End Sub



Zeichen_data:
Data &B00000000                                  'Zelle 0 im EEProm nicht benutzen!!!
Data &B11111111 , &B10111101 , &B10000000 , &B10111111 , &B11111111      '1
Data &B10111101 , &B10011110 , &B10101110 , &B10110110 , &B10111001      '2
Data &B00000000 , &B00000000 , &B00000000 , &B00000000 , &B00000000      '3 TEST

---

Leider ist die gleichmäßige Ausleuchtung sehr schlecht...
Wäre es nicht eigentlich besser die Zeilen immer frei zu geben und den spalten ein Bitmuster zu geben?
Oder müsste man das Programm mit Absicht verlangsamen, sodass die LEDs länger angesprochen werden? Waitus XX ?

Ich habe noch ein weiteres Programm gefunden, das eine Matrix ansteuern kann

Code:

---


$regfile = "m16DEF.DAT"
$crystal = 16000000
$baud = 19200


Dim A(7) As Byte

Dim Leds As Byte
Dim I As Byte
Dim J As Byte

Config Porta = Output
Porta = 0

Config Portc = Output
Portc = &HFF

Restore Dotmatrix

For I = 1 To 8
    Read A(i)
Next

Do


For I = 0 To 6
 Portc = &HFF
 Reset Portc.i
 J = I + 1
 Waitus 750
 Porta = A(j)
 Next
Loop
End

Dotmatrix:
Data &B11100110 , &B11100100 , &B11100100 , &B11100100 , &B11100100 , &B11101110 , &B11100100
Data &B11110001 , &B11100000 , &B11100000 , &B11100000 , &B11100000 , &B11101110 , &B11101110

---

Nur habe ich es da leider noch nicht geschafft in die zweite "Datenzeile" zu springen, wie es mit dem deinem Programm so einfach war.



Mfg Tryan[code]

Die Helligkeit der LEDs ändert sich halt mit der Anzeigedauer und der gewünschten Refresh-Rate.
Die LEDs ohne Pause durchrattern zu lassen gibt die meisten FPS, aber wenn der µC vor jeder Zeile ein paar Zyklen rumkramen muss, dann wird das Bild schnell dunkel, weil er länger nachdenkt als das Bild zu zeigen.

Ein paar Waitms vor der nächsten Zeile kehren das Verhältnis dann um, die FPS werden aber weniger.

Am saubersten wirds mit einem Timer-Interrupt, der dem µC Raum für eventulle Berechnungen läßt und für eine feste Framrate sorgt.

Ganz wichtig ist auf jeden Fall das schwarz-schalten der Reihe vor dem einlesen des neuen Bitmusters in die Spalte. Ansonsten bekommt man Geisterbilder.
Auch kann die letzte/erste Zeile unterschiedlich hell sein, wenn der µC nach jedem Volldurchgang noch was anderes macht...

Zitat:

---

Zitat von Tryan

Nur habe ich es da leider noch nicht geschafft in die zweite "Datenzeile" zu springen, wie es mit dem deinem Programm so einfach war.

---

In diesem Programm werden die Data Zeilen mit dem Read Befehl in ein Array geschrieben. Mit Read kannst du nur sequentiell ab dem Restore Label einlesen. Du musst also entweder alles in ein genügend großes Array einlesen (z.B. AR(100)), oder du fügst vor jedem Zeichen ein neues Label ein. Dann muss aber dein Restore immer auf verschiedene Label gehen.
Auch in diesem Programm kannst du die Lookup-Funktion benutzen, um von einer beliebigen Stelle einzulesen.

Für die gleichmäßige Ausleuchtung müsstest du mal mehr von dem Gesamtsystem erzählen. Gibt es z.B. mehrere dieser 5x7 Anzeigen und hast du vielleicht zeitaufwändige Berechnungen vor dem Anzeigen zu machen und so weiter.
Ansonsten gilt das was Stefan sagte. Lass einen Timer laufen, der bei jedem Überlauf eine Spalte weiterspringt und dann die Werte anzeigt. Dann sind alle immer gleichlang. Und mit der Zeit zwischen zwei Überläufen kannst du die Helligkeit steuern.

Gruß

Rolf

Danke für eure Hilfe soweit.
Wenn das Programm irgendwann mal fertig ist soll es zwei Aufgaben erfüllen.

1. Frequenz-messen und auf ein LCD anzeigen.
Das ist schon soweit fertig. Habe dafür Timer1 und den ICP genutzt.

2. Taste 1 => zeigt eine 1 bei der Matrix an
Taste 2 => zeigt eine 2 bei der Matrix an
usw.....

Da ich leider mit Arrays noch nicht gearbeitet habe, stehe ich da ganz schön auf dem schlauch ;)
Mit dem Timer ist es eine gut Idee.
Aber wenn nur eine LED in einer Spalte anzeigt wird, wird diese doch heller sein, als z.b. 7 oder?

Wenn dies der Fall ist, wäre es doch besser den Spalten ein Bitmuster zu geben und die Zeilen nach und nach freizuschalten....

Mfg Tryan

P.S. sorry für die ganzen fragen ;)

Nein, die LEDs einer Spalte sind alle einzeln geschaltet - leuchten also immer gleich hell.

Zitat:

---

Zitat von Tryan

2. Taste 1 => zeigt eine 1 bei der Matrix an
Taste 2 => zeigt eine 2 bei der Matrix an
usw.....

---

Wenn du nur die zwei Zustände anzeigen willst, wäre es dann nicht besser, nur eine LED pro Zustand oder maximal eine 7-Segment Anzeige für beide Ziffern zusammen zu verwenden? Oder hat die Matrix noch eine andere Anzeigefunktion?

Gruß

Rolf

Es kommen noch mehr Tasten hinzu und es müssen auch Buchstaben angezeigt werden wie z.b. ein "R" und darum hab ich mit für die 5x7 Matrix entschieden.

Mfg Tryan

Hi for_ro,

leider komm ich mit dem Timer Interrupt bei deinem Programm nicht weiter..
Wo genau muss ich dein Programm unterrechen, sodass ich die LEDs gleich hell leuchten?

Mfg Tryan

ich denke mir das ungefähr so:

Code:

---

$regfile = "m16DEF.DAT"
$crystal = 16000000
Config Porta = Input
Config Portb = Output
Config Portc = Output
Config Portd = Output

Dim Offset As Word                                      'kann auch byte sein, wenn du nicht mehr als 50 Zeichen brauchst
Dim Zeichen As Byte
Dim Spalte As Byte
Dim Werte As Byte

Config Timer0 = Timer , Prescale = 64                  'timer läuft alle 16.000.000/64/256=1000.stel Sekunde über, also etwa jede ms
On Timer0 Timer0_isr
Enable Timer0
Enable Interrupts
Spalte = 0
Do
  Zeichen = Asc( "2")
Loop

Timer0_isr:
  Offset = Zeichen - 49                                'sucht Werte für Zeichen "1" ab EEProm Adresse 1
  Offset = Offset * 5                                  'immer 5 Werte pro Zeichen
  Incr Spalte
  If Spalte = 6 Then
      Spalte = 1
  End If
  Offset = Offset + Spalte
  Portd = 0                                            'zum Verhindern von Geisterbildern
  'werte=lookup(offset,zeichen_data)
  Readeeprom Werte , Offset
  'Print Spalte ; ":" ; Bin(werte)                    'nur zum Testen, ACHTUNG!!! langsam
  Portc = Werte                                        'lädt die Werte
  Portd.spalte = 1                                    'Gibt die Spalte frei
Return

'zeichen_data:
$eeprom
Data &B00000000                                        'Zelle 0 im EEProm nicht benutzen!!!
Data &B11111111 , &B10111101 , &B10000000 , &B10111111 , &B11111111      '1
Data &B10111101 , &B10011110 , &B10101110 , &B10110110 , &B10111001      '2

---

Musst du mal auf deiner Hardware ausprobieren, im Simulator geht es.

Hi for_ro
erstmal danke für deine ganze mühe!
Die Ausleuchtung ist schon deutlich besser geworden, jedoch immer noch nicht gleichmäßig.
Leider erkennt man das auf einem Foto nicht so gut darum habe ich mal Paint an geschmissen um es zu verdeutlichen. (siehe Anhang).

Aber es macht irgendwo auch sinn das das die LEDS in der mitte dunkler sind als die Außen. Der Strom verteilt sich auf die 7 LEDs und links und recht der "1" nur auf eine bzw. auf zwei Leds. Darum leuchten sie ungleichmäßig...

Ist diese Problem überhaupt Software technisch zu lösen? Oder muss das per Hardware gelöst werden ( z.b. über Transistoren?)?

Mfg Tryan

Wie hast du die ganze Sache denn angeschlossen?
Schau mal das Jpeg im Anhang, wie ich mir das vorstelle.

Gruß

Rolf

Ich habe es so angeschlossen (siehe Anhang).
Ich habe so gedacht das ich jede LED einzeln ansteuere, sodass ich auf eine Treiber stufe verzichten kann...

mfg Tryan

Damit hast du doch nicht jede LED einzeln angesteuert!
Das geht auch gar nicht, sonst müsstest du ja 35 Ausgänge benutzen.
Nur jetzt hast du 7 LEDs an einem Port Pin hängen. Das geht nicht. Schau dir mal im Datenblatt die maximalen Ströme in einen PIN an. Dann ist klar, dass die unterschiedlich hell leuchten, wenn in der Spalte nur eine oder alle sieben LEDs an sind.
Wie gesagt, ich würde einen Treiber mit 6 Ein-/Ausgängen davor schalten. Du hast jetzt 20% Duty Cycle, mit dem Treiber kannst du dann auch 40mA in jede LED lassen, sodass die Matrix eine vernünftige Helligkeit hat.
Und dann kann auch deinem µC nichts passieren.

Gruß

Rolf

Warum brauch ich 35 Ausgänge? 7 Zeilen-Ausgänge und 5 Spalten- Ausgänge reichen doch.
Ich kann doch nach und nach jede LED einzeln durch an und ausschalten der Ports ansteuern und, wenn dies schnell genug passiert kann ich Zahlen und Buchstaben mir anzeigen lassen.
Ich habe mir schon gedacht das der Port mir dann nicht genug Strom liefern kann, wenn alle gleichzeitig in einer Spalte leuchten. Um dies zu umgehen wollte ich nach und nach die LEDs durchschalten.
Ich hoffe du verstehst was ich meine... ;)
Meinst du, wie es vor hatte, ist Blödsinn und der Programmieraufwand ist zu groß?

Mfg Tryan

Klar kannst du die LEDs so wie du sagst einzeln ansteuern. Das ist dann so, wie du anfangs das gemacht hast.
Allerdings bedeutet das, dass jede LED nur max. 1/35 der Zeit an ist, also weniger als 3%. Da wirst du keine vernünftige Helligkeit hinbekommen.

Gruß

Rolf

Hi for_ro,
ich hab endlich meine ULN2003 bekommen und natürlich gleich ausprobiert doch leider bleibt jetzt die anzeige dunkel. Ob die Signale nicht durch den ULN2003 durch kommen würden.
Ich habe es so angeschlossen wie am Anhang.
Vielleicht hast du ja eine Idee warum es nicht funktioniert.

Mfg Tryan

Hallo Tyran,
schau dir noch mal meine Zeichnung an, wo die Widerstände hingehören. Du musst sehen, dass immer nur die gleiche Anzahl LED zu einem Widerstand gehören, ansonsten bekommst du Helligkeitsunterschiede. Also die Widerstände in die Zeilen.
Außerdem stimmen jetzt die abgespeicherten Bytewerte nicht mit dem Anschluss-Schema überein. Der ULN2003 schaltet dir den Ausgang an Masse wenn am Eingang eine 1 liegt. Die Spalten sind also richtig, es ist immer nur eine auf 1.
Entsprechend müssen die PortB Ausgänge auf 1 gehen, wenn ein Punkt an sein soll. Im Moment stehen sie auf 0. Also musst du die Bytes genau invertieren.

Gruß

Rolf

Hi for_ru,
okay hab das Layout verändert (siehe Anhang), kann aber erst am Montag meine "test-Platine" verändern. Ich hoffe nun das es so richtig ist.

Zum Programm Muss ich jetzt also einfach diese Daten:

Code:

---

Data &B11000001 , &B10101110 , &B10110110 , &B10111010 , &B11000001      '0
Data &B11111111 , &B10111101 , &B10000000 , &B10111111 , &B11111111      '1
Data &B10111101 , &B10011110 , &B10101110 , &B10110110 , &B10111001      '2
Data &B11011110 , &B10111110 , &B10110110 , &B10110010 , &B11001100      '3
Data &B11100111 , &B11101011 , &B11101101 , &B10000000 , &B11101111      '4
Data &B11010000 , &B10110110 , &B10110110 , &B10110110 , &B11000110      '5

---

Inventieren?

Mfg TRyan

P.S. Danke für die ganze Hilfe. Ohne dich wäre ich wohl nie soweit gekommen.

Hi for_ro,
Also ich habe es mal so aufgebaut wie du es mir gezeigt hast.
Jedoch so bald ich Masse ans ULN2003 anschließe geht die Anzeige aus.
Macht auch Sinn wenn der ULN meinen Eingang auf Masse zieht.
Um eine LED zu leuchten zu bringen muss bei der Zeilen ein 0V anliegen und bei der Spalte 5V (natürlich mit Vorwiderstand). Ich verstehe einfach nicht wie das funktionieren soll, wenn ich auf beiden Seiten der LED 0V anliegen habe....
Und es würde auch nix bringen 5V an den Zeilen anzulegen, weil dann die Leds sperren und nicht leuchten würden..

Hallo Tryan,
ich befürchte, wir haben da die ganze Zeit an einander vorbei geredet.
Ich war immer davon ausgegangen, dass die LEDs genau anders herum angeschlossen sind. Jetzt verstehe ich, warum du das so machen wolltest.
Jetzt gibt es zwei Möglichkeiten:
1. Du nimmst den ULN2003 um die Zeilen anzusteuern, und die Spalten hängst du direkt an den µC. Vorteil: du brauchst keinen neuen Treiber. Nachteil: du musst jetzt die 7 Zeilen durchgehen, also nur noch 1/7 der Zeit pro LED Zeile. Abspeichern musst du dann die Spalten Werte, du brauchst 7 Bytes pro Zeichen und nicht mehr 5.
2. Du besorgst dir einen UDN2981. Den setzt du anstelle des ULN2003 ein und brauchst sonst nichts zu ändern.
Sorry für das Missverständnis.

Gruß

Rolf

Man könnte alterantiv auch eine andere Anzeige besorgen, wo die LEDs genau andersherum drin sind.

Hi for_ro,
alles nicht so schlimm, ich habe jetzt die Widerstände in die Zeilen eingebaut und die Ausleuchtung ist jetzt zu 95% optimal. Bin mir jetzt nicht ganz sicher warum, aber ich bin voll zu frieden ;)

Jetzt wollte ich gerne noch die Helligkeit in zwei stufen dimmen.
Am Tag soll die Ausleuchtung 100% sein (bzw. bei mir 95% ;))
und abends soll es nur noch 50% sein, sodass die Anzeige nicht blendet.

Ich hatte mir gedacht, dass ich einfach die Zeit wie lange eine Spalte ansteuere verändern müsste...
Macht man das mit PWM?
Leider sind T0 und T1 schon belegt ist Timer2 auch in der Lage ein PWM-Signal zu erzeugen?

Mfg Tryan

Wie willst du denn die Umschaltung realisieren, über die Zeit oder einen Schalter, oder einen Fotowiderstand?

Den Code würde ich so ändern (praktisch Soft-PWM), da du eh schon alles beisammen hast:

Code:

---

$regfile = "m16DEF.DAT"
$crystal = 16000000
Config Porta = Input
Config Portb = Output
Config Portc = Output
Config Portd = Output

Dim Offset As Word                                          'kann auch byte sein, wenn du nicht mehr als 50 Zeichen brauchst
Dim Zeichen As Byte
Dim Spalte As Byte
Dim Werte As Byte
Dim Display_off As Byte , Max_display_off As Byte
Dim Blinken As Byte

Max_display_off = 1                                        'diesen Wert noch ausprobieren

Config Dcf77 = Pind.2 , Check = 2 , Timer = 1 , Timer1sec = 1 , Debug = 1 , Sectic = 1

Config Timer0 = Timer , Prescale = 64                      'timer läuft alle 16.000.000/256/256=250.stel Sekunde über, also etwa alle 4ms
On Timer0 Timer0_isr
Enable Timer0
Enable Interrupts
Spalte = 0
Do
  Zeichen = Asc( "2")
Loop

Timer0_isr:
  Offset = Zeichen - 49                                    'sucht Werte für Zeichen "1" ab EEProm Adresse 1
  Offset = Offset * 5                                      'immer 5 Werte pro Zeichen
  If Spalte = 6 Then
      Spalte = 1
  End If
  Offset = Offset + Spalte
  Werte = Lookup(offset , Zeichen_data)
  Incr Display_off
  Portd = 0                                                'zum Verhindern von Geisterbildern
  If Display_off > Max_display_off And Blinken = 0 Then    'damit bleibt das Zeichen immer für eine bestimmte Zeit aus
      Display_off = 0
      Portc = Werte                                        'lädt die Werte
      Portd.spalte = 1                                      'Gibt die Spalte frei
      Incr Spalte
  End If
Return

Sectic:
  Toggle Blinken
Return


Zeichen_data:
Data &B11111111 , &B10111101 , &B10000000 , &B10111111 , &B11111111      '1
Data &B10111101 , &B10011110 , &B10101110 , &B10110110 , &B10111001      '2

---

Wenn Max_display_off auf 1 steht, bedeutet das, dass er immer einen Zyklus aussetzt. Du kannst die Zahl auch erhöhen.
Wenn dir die Schritte zu groß sind, können wir das bestimmt auch noch verändern.
Es kann sein, dass die Anzeige dann anfängt zu flimmern, weil wir praktisch auch die Frequenz runtersetzen. Dann müssen wir den Timer etwas anders laufen lassen.
Probier's mal aus.

Gruß

Rolf

Hi for_ro
Ab heute bist du offiziell für mich der Bascom Gott ;)
Die Umschaltung werde ich mit einem Schalter machen.
So die letze frage, dann sollte das Projekt so weit fertig sein, ist es möglich die Zahlen Blinken zu lassen...?
Ich kann es mit nicht vorstellen, da man ja alle gleichzeitig An und wieder Aus machen müsst und das z.b. in einem 0.5 sek takt. Da aber die Ansteuerung immer nach und nach verläuft, würde es nur zu einem flackern kommen oder?

Mfg Tryan

Zitat:

---

Zitat von Tryan

Hi for_ro
Ab heute bist du offiziell für mich der Bascom Gott ;)

---

Ne, ne, das ist ein bisschen viel.

Zitat:

---

Zitat von Tryan

So die letze frage, dann sollte das Projekt so weit fertig sein, ist es möglich die Zahlen Blinken zu lassen...?

---

Das Blinken habe ich dir grundsätzlich in den Code oben eingebaut. Da du Config DCF77 benutzt, kannst du auch noch Sectic=1 anhängen. Dann wird im Sekundentakt ein Label Sectic angesprungen. Dort schaltest du das Blinken ein und aus.
Aber du musst es jetzt noch irgendwie generell einschalten, also auch wieder über einen externen Schalter oder so.

Gruß

Rolf

Ah das ist ja super ich dachte es wäre gar nicht möglich...
Muss ich das "Label Sectic" selbst definieren?
Oder mach ich das mit dem Display_off?
Ich hab es so versucht (siehe Anhang) Jedoch läuft er wie es mir dacht habe, von links nach rechts durch und blinkt nicht..

Code:

---

$regfile = "m16DEF.DAT"
$crystal = 16000000
Config Porta = Input
Config Portb = Output
Config Portc = Output
Config Portd = Output

Dim Offset As Word                                'kann auch byte sein, wenn du nicht mehr als 50 Zeichen brauchst
Dim Zeichen As Byte
Dim Spalte As Byte
Dim Werte As Byte
Dim Display_off As Byte , Max_display_off As Byte ,
Dim Blink_an As Byte , Max_blink_an As Byte

Config Dcf77 = Pind.7 , Check = 2 , Timer = 1 , Timer1sec = 1 , Debug = 1 , Sectic = 1

Config Timer0 = Timer , Prescale = 64            'timer läuft alle 16.000.000/256/256=250.stel Sekunde über, also etwa alle 4ms
On Timer0 Timer0_isr
Enable Timer0
Enable Interrupts
Spalte = 0
Do
  Zeichen = Asc( "2")
  If Pina.7 = 1 Then Max_display_off = 4
  If Pina.7 = 0 Then Max_display_off = 0

  If Pina.6 = 1 Then Max_blink_an = 40
  If Pina.6 = 0 Then Max_blink_an = 0
Loop

Timer0_isr:
  Offset = Zeichen - 49
  Offset = Offset * 5                            'immer 5 Werte pro Zeichen
  If Spalte = 5 Then
      Spalte = 0
  End If
  Offset = Offset + Spalte
  Werte = Lookup(offset , Zeichen_data)
  Incr Display_off
  Incr Blink_an
  Portd = 0                                      'zum Verhindern von Geisterbildern
  If Display_off > Max_display_off Then          'damit bleibt das Zeichen immer für eine bestimmte Zeit aus
      Display_off = 0
      If Blink_an > Max_blink_an Then
      Blink_an = 0
      Portb = Werte                              'lädt die Werte
      Portd.spalte = 1                            'Gibt die Spalte frei
      Incr Spalte
  End If
  End If
Return

Zeichen_data:
Data &B11111111 , &B10111101 , &B10000000 , &B10111111 , &B11111111      '1
Data &B10111101 , &B10011110 , &B10101110 , &B10110110 , &B10111001      '2

---

Mfg Tryan

Probier erst mal meinen Code oben aus. Dann können wir weitersehen.

Das ist doch dein Code, dass Dimmen funktioniert wunderbar... habe jetzt versucht das Blinken einzufügen..

Mfg Tryan

Ne, ich meinte diesen hier von oben:

Code:

---

$regfile = "m16DEF.DAT"
$crystal = 16000000
Config Porta = Input
Config Portb = Output
Config Portc = Output
Config Portd = Output

Dim Offset As Word                                          'kann auch byte sein, wenn du nicht mehr als 50 Zeichen brauchst
Dim Zeichen As Byte
Dim Spalte As Byte
Dim Werte As Byte
Dim Display_off As Byte , Max_display_off As Byte
Dim Blinken As Byte

Max_display_off = 1                                        'diesen Wert noch ausprobieren

Config Dcf77 = Pind.2 , Check = 2 , Timer = 1 , Timer1sec = 1 , Debug = 1 , Sectic = 1

Config Timer0 = Timer , Prescale = 64                      'timer läuft alle 16.000.000/256/256=250.stel Sekunde über, also etwa alle 4ms
On Timer0 Timer0_isr
Enable Timer0
Enable Interrupts
Spalte = 0
Do
  Zeichen = Asc( "2")
Loop

Timer0_isr:
  Offset = Zeichen - 49                                    'sucht Werte für Zeichen "1" ab EEProm Adresse 1
  Offset = Offset * 5                                      'immer 5 Werte pro Zeichen
  If Spalte = 6 Then
      Spalte = 1
  End If
  Offset = Offset + Spalte
  Werte = Lookup(offset , Zeichen_data)
  Incr Display_off
  Portd = 0                                                'zum Verhindern von Geisterbildern
  If Display_off > Max_display_off And Blinken = 0 Then    'damit bleibt das Zeichen immer für eine bestimmte Zeit aus
      Display_off = 0
      Portc = Werte                                        'lädt die Werte
      Portd.spalte = 1                                      'Gibt die Spalte frei
      Incr Spalte
  End If
Return

Sectic:
  Toggle Blinken
Return


Zeichen_data:
Data &B11111111 , &B10111101 , &B10000000 , &B10111111 , &B11111111      '1
Data &B10111101 , &B10011110 , &B10101110 , &B10110110 , &B10111001      '2

---

Gruß

Rolf

Ah sorry das hatte ich nicht gesehen...

Also das Dimmen steuere ich so an:
If Pina.7 = 1 Then Max_display_off = 4
If Pina.7 = 0 Then Max_display_off = 0

Aber wie steuere ich das Blinken an?
Muss ich zum Sectic springen damit die Anzeige blinkt?
z.b. If Pina.6 = 1 Then "springe zu Sectic" ?

Mfg Tryan

Funktioniert denn das Blinken mit meinem Code im 1-Sekundentakt?

Gruß

Rolf