- LiTime Speicher und Akkus         
Ergebnis 1 bis 3 von 3

Thema: Abspielen einer Sounddatei durch Aktivierung eines Bewegungsmelders

  1. #1

    Abspielen einer Sounddatei durch Aktivierung eines Bewegungsmelders

    Anzeige

    Powerstation Test
    Hallo,
    ich versuche seit einiger Zeit, durch die Aktivierung eines Bewegungsmelders (HC-SR501 PIR) eine Sounddatei abzuspielen. Als MP3 Player benutze ich den Serial MP3 Player von Catalex und einen Arduino UNO. Den Code habe ich von hier unter "Test the Device":
    https://create.arduino.cc/projecthub/jav...lex-2effef
    Der Code hat ohne Probleme funktioniert. Danach habe ich versucht, das Abspielen durch den Bewegungsmelder zu starten, und habe dementsprechend Code hinzugefügt, so wie es hier beschrieben wurde https://funduino.de/nr-8-bewegungsmelder :
    Code:
    int bewegung=7;
    int bewegungsstatus=0;
    
    void setup() {
    pinMode(Bewegung, INPUT);
    }
    
    void loop() {
    
    bewegungsstatus=digitalRead(bewegung);
    
    
    if (bewegungsstatus == LOW) {
    sendCommand(CMD_PAUSE);
    } else {
    sendCommand(CMD_FOLDER_CYCLE,1,1);
    }
    }
    Doch als ich den Text hinzugefügt habe, begann die Musik dauerhaft zu spielen, auch wenn der Bewegungsmelder nichts sehen konnte oder er komplett entfernt wurde. Der Bewegungsmelder funktioniert sonst gut, es muss also ein Fehler im Code sein oder diese Art von Code für den Bewegungsmelder lässt sich hier nicht anwenden.

    Irgendwelche Ideen?
    Vielen Dank


    Hier nochmal der ganze Code:

    Code:
    #include <SoftwareSerial.h>
    
    int bewegung=7;
    int bewegungsstatus=0;
    
    #define ARDUINO_RX 5  //should connect to TX of the Serial MP3 Player module
    #define ARDUINO_TX 6  //connect to RX of the module
    SoftwareSerial mp3(ARDUINO_RX, ARDUINO_TX);
    // Uncomment next line if you are using an Arduino Mega.
    //#define mp3 Serial3    // Connect the MP3 Serial Player to the Arduino MEGA Serial3 (14 TX3 -> RX, 15 RX3 -> TX)
    static int8_t Send_buf[8] = {0}; // Buffer for Send commands.  // BETTER LOCALLY
    static uint8_t ansbuf[10] = {0}; // Buffer for the answers.    // BETTER LOCALLY
    String mp3Answer;           // Answer from the MP3.
    String sanswer(void);
    String sbyte2hex(uint8_t b);
    /************ Command byte **************************/
    #define CMD_NEXT_SONG     0X01  // Play next song.
    #define CMD_PREV_SONG     0X02  // Play previous song.
    #define CMD_PLAY_W_INDEX  0X03
    #define CMD_VOLUME_UP     0X04
    #define CMD_VOLUME_DOWN   0X05
    #define CMD_SET_VOLUME    0X06
    #define CMD_SNG_CYCL_PLAY 0X08  // Single Cycle Play.
    #define CMD_SEL_DEV       0X09
    #define CMD_SLEEP_MODE    0X0A
    #define CMD_WAKE_UP       0X0B
    #define CMD_RESET         0X0C
    #define CMD_PLAY          0X0D
    #define CMD_PAUSE         0X0E
    #define CMD_PLAY_FOLDER_FILE 0X0F
    #define CMD_STOP_PLAY     0X16  // Stop playing continuously. 
    #define CMD_FOLDER_CYCLE  0X17
    #define CMD_SHUFFLE_PLAY  0x18 //
    #define CMD_SET_SNGL_CYCL 0X19 // Set single cycle.
    #define CMD_SET_DAC 0X1A
    #define DAC_ON  0X00
    #define DAC_OFF 0X01
    #define CMD_PLAY_W_VOL    0X22
    #define CMD_PLAYING_N     0x4C
    #define CMD_QUERY_STATUS      0x42
    #define CMD_QUERY_VOLUME      0x43
    #define CMD_QUERY_FLDR_TRACKS 0x4e
    #define CMD_QUERY_TOT_TRACKS  0x48
    #define CMD_QUERY_FLDR_COUNT  0x4f
    /************ Opitons **************************/
    #define DEV_TF            0X02
    /*********************************************************************/
    void setup()
    {
      pinMode(bewegung, INPUT);
      Serial.begin(9600);
      mp3.begin(9600);
      delay(500);
      sendCommand(CMD_SEL_DEV, 0, DEV_TF);
      delay(500);
    }
    void loop()
    {
      bewegungsstatus=digitalRead(bewegung);
      if (bewegungsstatus == LOW) {
          sendCommand(CMD_PAUSE);
        } else {
            sendCommand(CMD_FOLDER_CYCLE,1,1);
          }
      char c = ' ';
      // If there a char on Serial call sendMP3Command to sendCommand
      if ( Serial.available() )
      {
        c = Serial.read();
        sendMP3Command(c);
      } 
      // Check for the answer.
      if (mp3.available())
      {
        Serial.println(decodeMP3Answer());
      }
      delay(100);
    }
    /********************************************************************************​/
    /*Function sendMP3Command: seek for a 'c' command and send it to MP3  */
    /*Parameter: c. Code for the MP3 Command, 'h' for help.                                                                                                         */
    /*Return:  void                                                                */
    void sendMP3Command(char c) {
      switch (c) {
        case '?':
        case 'h':
          Serial.println("HELP  ");
          Serial.println(" p = Play");
          Serial.println(" P = Pause");
          Serial.println(" > = Next");
          Serial.println(" < = Previous");
          Serial.println(" s = Stop Play"); 
          Serial.println(" + = Volume UP");
          Serial.println(" - = Volume DOWN");
          Serial.println(" c = Query current file");
          Serial.println(" q = Query status");
          Serial.println(" v = Query volume");
          Serial.println(" x = Query folder count");
          Serial.println(" t = Query total file count");
          Serial.println(" f = Play folder 1.");
          Serial.println(" S = Sleep");
          Serial.println(" W = Wake up");
          Serial.println(" r = Reset");
          break;
        case 'p':
          Serial.println("Play ");
          sendCommand(CMD_PLAY);
          break;
        case 'P':
          Serial.println("Pause");
          sendCommand(CMD_PAUSE);
          break;
        case '>':
          Serial.println("Next");
          sendCommand(CMD_NEXT_SONG);
          sendCommand(CMD_PLAYING_N); // ask for the number of file is playing
          break;
        case '<':
          Serial.println("Previous");
          sendCommand(CMD_PREV_SONG);
          sendCommand(CMD_PLAYING_N); // ask for the number of file is playing
          break;
        case 's':
          Serial.println("Stop Play");
          sendCommand(CMD_STOP_PLAY);
          break;
        case '+':
          Serial.println("Volume Up");
          sendCommand(CMD_VOLUME_UP);
          break;
        case '-':
          Serial.println("Volume Down");
          sendCommand(CMD_VOLUME_DOWN);
          break;
        case 'c':
          Serial.println("Query current file");
          sendCommand(CMD_PLAYING_N);
          break;
        case 'q':
          Serial.println("Query status");
          sendCommand(CMD_QUERY_STATUS);
          break;
        case 'v':
          Serial.println("Query volume");
          sendCommand(CMD_QUERY_VOLUME);
          break;
        case 'x':
          Serial.println("Query folder count");
          sendCommand(CMD_QUERY_FLDR_COUNT);
          break;
        case 't':
          Serial.println("Query total file count");
          sendCommand(CMD_QUERY_TOT_TRACKS);
          break;
        case 'f':
          Serial.println("Playing folder 1");
          sendCommand(CMD_FOLDER_CYCLE, 1, 0);
          break;
        case 'S':
          Serial.println("Sleep");
          sendCommand(CMD_SLEEP_MODE);
          break;
        case 'W':
          Serial.println("Wake up");
          sendCommand(CMD_WAKE_UP);
          break;
        case 'r':
          Serial.println("Reset");
          sendCommand(CMD_RESET);
          break;
      }
    }
    /********************************************************************************​/
    /*Function decodeMP3Answer: Decode MP3 answer.                                  */
    /*Parameter:-void                                                               */
    /*Return: The                                                  */
    String decodeMP3Answer() {
      String decodedMP3Answer = "";
      decodedMP3Answer += sanswer();
      switch (ansbuf[3]) {
        case 0x3A:
          decodedMP3Answer += " -> Memory card inserted.";
          break;
        case 0x3D:
          decodedMP3Answer += " -> Completed play num " + String(ansbuf[6], DEC);
          break;
        case 0x40:
          decodedMP3Answer += " -> Error";
          break;
        case 0x41:
          decodedMP3Answer += " -> Data recived correctly. ";
          break;
        case 0x42:
          decodedMP3Answer += " -> Status playing: " + String(ansbuf[6], DEC);
          break;
        case 0x48:
          decodedMP3Answer += " -> File count: " + String(ansbuf[6], DEC);
          break;
        case 0x4C:
          decodedMP3Answer += " -> Playing: " + String(ansbuf[6], DEC);
          break;
        case 0x4E:
          decodedMP3Answer += " -> Folder file count: " + String(ansbuf[6], DEC);
          break;
        case 0x4F:
          decodedMP3Answer += " -> Folder count: " + String(ansbuf[6], DEC);
          break;
      }
      return decodedMP3Answer;
    }
    /********************************************************************************​/
    /*Function: Send command to the MP3                                             */
    /*Parameter: byte command                                                       */
    /*Parameter: byte dat1 parameter for the command                                */
    /*Parameter: byte dat2 parameter for the command                                */
    void sendCommand(byte command){
      sendCommand(command, 0, 0);
    }
    void sendCommand(byte command, byte dat1, byte dat2){
      delay(20);
      Send_buf[0] = 0x7E;    //
      Send_buf[1] = 0xFF;    //
      Send_buf[2] = 0x06;    // Len
      Send_buf[3] = command; //
      Send_buf[4] = 0x01;    // 0x00 NO, 0x01 feedback
      Send_buf[5] = dat1;    // datah
      Send_buf[6] = dat2;    // datal
      Send_buf[7] = 0xEF;    //
      Serial.print("Sending: ");
      for (uint8_t i = 0; i < 8; i++)
      {
        mp3.write(Send_buf[i]) ;
        Serial.print(sbyte2hex(Send_buf[i]));
      }
      Serial.println();
    }
    /********************************************************************************​/
    /*Function: sbyte2hex. Returns a byte data in HEX format.                       */
    /*Parameter:- uint8_t b. Byte to convert to HEX.                                */
    /*Return: String                                                                */
    String sbyte2hex(uint8_t b)
    {
      String shex;
      shex = "0X";
      if (b < 16) shex += "0";
      shex += String(b, HEX);
      shex += " ";
      return shex;
    }
    /********************************************************************************​/
    /*Function: shex2int. Returns a int from an HEX string.                         */
    /*Parameter: s. char *s to convert to HEX.                                      */
    /*Parameter: n. char *s' length.                                                */
    /*Return: int                                                                   */
    int shex2int(char *s, int n){
      int r = 0;
      for (int i=0; i<n; i++){
         if(s[i]>='0' && s[i]<='9'){
          r *= 16; 
          r +=s[i]-'0';
         }else if(s[i]>='A' && s[i]<='F'){
          r *= 16;
          r += (s[i] - 'A') + 10;
         }
      }
      return r;
    }
    /********************************************************************************​/
    /*Function: sanswer. Returns a String answer from mp3 UART module.          */
    /*Parameter:- uint8_t b. void.                                                  */
    /*Return: String. If the answer is well formated answer.                        */
    String sanswer(void)
    {
      uint8_t i = 0;
      String mp3answer = "";
      while (mp3.available() && (i < 10))
      {
        uint8_t b = mp3.read();
        ansbuf[i] = b;
        i++;
        mp3answer += sbyte2hex(b);
      }
      if ((ansbuf[0] == 0x7E) && (ansbuf[9] == 0xEF))
      {
        return mp3answer;
      }
      return "???: " + mp3answer;
    }

  2. #2
    Erfahrener Benutzer Robotik Visionär Avatar von 021aet04
    Registriert seit
    17.01.2005
    Ort
    Niklasdorf
    Alter
    36
    Beiträge
    5.052
    Ich habe mir den Code nicht angesehen und ich arbeite auch nicht mit der Arduino IDE, hätte aber noch ein paar Ideen.

    Ist der Pullup Widerstand eingeschalten bzw hast du extern einen Pullup Widerstand angebracht? Wenn das nicht der Fall ist hast du keine definierten High/Low Pegel, außer der Ausgang ist ein Push/Pull.
    Ich würde zuerst ohne Bewegungsmelder Testen. Einfach eine Taste anschließen (mit Pullup Widerstand).

    MfG Hannes

  3. #3
    Erfahrener Benutzer Roboter-Spezialist
    Registriert seit
    13.01.2014
    Beiträge
    454
    Blog-Einträge
    3
    Was passiert, wenn mehrmals hintereinander das Pause-Kommando gesendet wird?
    Dieser Code sendet nur bei Änderung am Bewegungspin Signale an den MP3-Player.
    Code:
    #define PIN_BEWEGUNG 7
     
    void setup() { 
      pinMode(PIN_BEWEGUNG, INPUT); 
    }
    
    void loop() { 
      static bool bewegung_alt = false;
      bool bewegung = digitalRead(PIN_BEWEGUNG);
      if(bewegung != bewegung_alt) {
        bewegung_alt = bewegung;
        if(bewegung) {
          sendCommand(CMD_PAUSE);
        } else {
          sendCommand(CMD_FOLDER_CYCLE,1,1);
        }
      }
    }

Ähnliche Themen

  1. Begrenzung einer durch Motor induzierten Spannung
    Von Cartman05 im Forum Elektronik
    Antworten: 3
    Letzter Beitrag: 22.11.2010, 17:12
  2. Antworten: 8
    Letzter Beitrag: 13.10.2007, 20:16
  3. Sounddatei über Beeper ausgeben?
    Von 3dfreak im Forum Robby CCRP5
    Antworten: 7
    Letzter Beitrag: 31.07.2007, 17:15
  4. Ungewollte Aktivierung einer Funktion. Bitte helft mir!!!
    Von UriAn im Forum Basic-Programmierung (Bascom-Compiler)
    Antworten: 3
    Letzter Beitrag: 24.01.2006, 19:38
  5. Positionsbestimmug durch Landmarken mit Hilfe einer Kamera
    Von buchse_04 im Forum Software, Algorithmen und KI
    Antworten: 11
    Letzter Beitrag: 16.06.2005, 10:00

Stichworte

Berechtigungen

  • Neue Themen erstellen: Nein
  • Themen beantworten: Nein
  • Anhänge hochladen: Nein
  • Beiträge bearbeiten: Nein
  •  

LiTime Speicher und Akkus